input_case nil$ in "kpack.red","lepten.red"$

% mu decay
% --------
mass p=1,p1=m1,p2=m2,p3=m3; mshell p,p1,p2,p3;
index l1,l2; MM:=-Tl(p,l2,p1,l1)*Tl(p2,l1,-p3,l2)/2;
remind l1,l2; % very simple result
let p.p1=1-(x2+x3)/2,p.p2=x2/2,p.p3=x3/2,
    p1.p2=(1+m3^2-m1^2-m2^2-x3)/2,p1.p3=(1+m2^2-m1^2-m3^2-x2)/2,
    p2.p3=(-1+m1^2-m2^2-m3^2+x2+x3)/2;
m1:=m2:=m3:=0$ % massless case
Gamma:=MM/2/(4*(2*pi)^3)/4;  % d Gamma / dx2 dx3
Gamma:=int(Gamma,x3,1-x2,1); % d Gamma / dx2
Gamma:=int(Gamma,x2,0,1);    % Gamma
Gamma0:=Gamma$ clear Gamma;

% Polarized mu
vector q,z; q:=p1+p3$ let p.z=0,p2.z=-x2/2*c,p1.z=-p2.z-p3.z;
index l1,l2; MMp:=64*(p-z).l1*p2.l2*(q.q*l1.l2+2*q.l1*q.l2)/12$
remind l1,l2; Gamma:=MMp/2/(4*(2*pi)^3)/4*x2;
Gamma:=int(Gamma,x2,0,1); clear MMp,Gamma;

% taking the electron mass into account
clear m2; Gamma:=MM/2/(4*(2*pi)^3)/4$
let abs(1-x2+m2^2)=1-x2+m2^2;
Dalitz(1,m2,0,0,x2/2,E3m,E3p)$
Gamma:=int(Gamma,x3,2*E3m,2*E3p); clear E3m,E3p;
load_package algint$ Gamma:=int(Gamma,x2,2*m2,1+m2^2)$
for all x let log(-x)=log(x);
for all x,y let log(x*y)=log(x)+log(y),log(x^y)=y*log(x);
Gamma:=Gamma$
for all x clear log(-x); for all x,y clear log(x*y),log(x^y);
Gamma/Gamma0; clear Gamma,Gamma0;

% nu-mu e -> mu nu-e
let p1.p2=(s-m2^2)/2,p.p3=(s-1)/2,p.p1=(1-t)/2,p2.p3=(m2^2-t)/2,
    p1.p3=(s+t-1-m2^2)/2,p.p2=(s+t)/2;
let abs(m2^2-s)=s-m2^2,abs(m2^2*s-m2^2-s^2+s)=(s-m2^2)*(s-1);
on gcd; sigma:=MM/(64*pi*JJ(s,0,m2)^2);      % d sigma / d t
Mandel(0,m2,1,0,s,tm,tp)$ sigma:=int(sigma,t,tp,tm)$
clear tm,tp; on factor; sigma; off factor;   % sigma

% e anti-nu-e -> mu anti-nu-mu
sigma:=sub(s=t,t=s,MM)/(64*pi*JJ(s,0,m2)^2)$ % d sigma / d t
on factor; sigma; off factor;
Mandel(0,m2,1,0,s,tm,tp)$
sigma:=int(sigma,t,tp,tm)$ clear tm,tp; on factor; sigma; % sigma

end;